VBA 自作のExcelアドインに、アドイン自身のアップデート機能をつける

業務で複数人が使うマクロはアドインを作って配布すると便利だ。アドインのリボンにマクロを登録しておけば、だれでも簡単に利用することができる。

ただ、そのアドイン自身を更新しようと思ったら、また配布しなおして利用者全員に再登録してもらわなければならない。手間もかかるし、人によっては方法がよくわからずにそのまま古いバージョンを使い続けるなんてこともあるだろう。

単に便利機能の追加だったら良いが、重要なバグに対する更新だったり、誤操作防止やセキュリティの向上を伴うアップデートだったりした場合、確実に全員のアドインを更新しておきたい。

今回はそんな時に役立つ手法を紹介する。

まずtest.xlamとしてリボン付きのアドインを作成し、標準のアドインフォルダに保存する。リボンのコマンドは次のとおり。

f:id:t-hom:20150626075139p:plain

アドインの標準モジュールに次のようなコードを入力し、保存したらそのアドインはC直下にもコピーしておく。
(実際の運用では共有フォルダなどにコピー)

Sub ShowVersion(control As IRibbonControl)
    MsgBox "これはVer2.0です。"
End Sub

Sub UpdateAddIn(control As IRibbonControl)
    Shell ("WScript.exe ""C:\AddInUpdater.vbs""")
    ThisWorkbook.Close
End Sub

これは上記のリボンから呼び出すことを想定しているが、リボンの作成方法はここでは説明しないので過去記事を参照してほしい。

thom.hateblo.jp

次に、次のコードでAddInUpdater.vbsを作成し、C直下に保存する。
(実際の運用では共有フォルダなどに保存)

Const GetAddInFrom = "C:\test.xlam"

MsgBox "アドインを更新します。OKをクリックした後、しばらくお待ちください。"
WScript.Sleep 3000
Call DeactivateAddIn
Call UpdateAddIn
Call ActivateAddIn
MsgBox "アドインを更新しました"


Sub DeactivateAddIn
	Set Excel = GetObject(, "Excel.Application")
	For Each x In Excel.AddIns
		If x.Name = "test.xlam" Then
			x.Installed = False
		End If
	Next
End Sub

Sub ActivateAddIn
	Set Excel = GetObject(, "Excel.Application")
	For Each x In Excel.AddIns
		If x.Name = "test.xlam" Then
			x.Installed = True
		End If
	Next
End Sub

Sub UpdateAddIn
	Set WS = WScript.CreateObject("WScript.Shell")
	UserProfile = WS.ExpandEnvironmentStrings("%USERPROFILE%")
	Set FSO = WScript.CreateObject("Scripting.FileSystemObject")
	FSO.CopyFile GetAddInFrom, UserProfile & "\AppData\Roaming\Microsoft\AddIns\", True
End Sub